home *** CD-ROM | disk | FTP | other *** search
/ Art Works / Art Works.iso / demos / audioworks / _audiodemo / _run < prev    next >
Encoding:
Text File  |  1994-04-05  |  3.6 KB  |  88 lines
  1. | !Run file for AudioWorks digital sound editor
  2. | This Run file contains user servicable parts. See the comments below.
  3.  
  4.  
  5. |----------------------------------------------------------------------------
  6. | Ensure enough memory available to run, and load our icon sprites
  7.  
  8. WimpSlot -min 240K -max 240K
  9. IconSprites <Obey$Dir>.!Sprites
  10.  
  11. |----------------------------------------------------------------------------
  12. | Set things up so that AudioWorks and DataVox files will run AudioWorks if
  13. | they are double-clicked (but only if no other application (!AudioCtrl)
  14. | has set these things up already)
  15.  
  16. Set File$Type_BD6 AudioWrk
  17. If "<Alias$@RunType_BD6>" = "" Then Set Alias$@RunType_BD6 Run <Obey$Dir>.!Run %%*0
  18.  
  19. Set File$Type_BD5 Envelope
  20. Set Alias$@RunType_BD5 Run <Obey$Dir>.!Run %%*0
  21.  
  22. Set File$Type_108 DataVox
  23. If "<Alias$@RunType_108>" = "" Then Set Alias$@RunType_108 Run <Obey$Dir>.!Run %%*0
  24.  
  25. |----------------------------------------------------------------------------
  26. | Ensure all the modules we need are present
  27.  
  28. RMEnsure FPEmulator 2.80 RMLoad System:Modules.FPEmulator
  29. RMEnsure FPEmulator 2.80 Error You need at least version 2.80 of the Floating Point Emulator
  30.  
  31. RMensure SharedClibrary 3.75 RMLoad System:Modules.CLib
  32. RMensure SharedClibrary 3.75 Error You need at least version 3.75 of the shared C library
  33.  
  34. RMEnsure IRQUtils 0.12 RMLoad System:Modules.IRQUtils
  35.  
  36. RMEnsure AudioManager 1.25 RMLoad <Obey$Dir>.RMStore.AManager
  37. RMensure AudioManager 1.25 Error You need at least version 1.25 of AudioManager
  38.  
  39. RMEnsure WimpKey 1.01 RMLoad <Obey$Dir>.RMStore.WimpKey
  40. RMensure WimpKey 1.01 Error You need at least version 1.01 of WimpKey
  41.  
  42. |----------------------------------------------------------------------------
  43. | AudioWorks application directory
  44. | Read-only resources must be placed in <AudioWorks$Dir>.Resources.
  45. | AudioWorks$Path is set up from this when the program is run.
  46.  
  47. Set AudioWorks$Dir <Obey$Dir>
  48.  
  49. |----------------------------------------------------------------------------
  50. | AudioWorks 'panic save' directory name (written to on fatal error)
  51. | The actual directory will be CDIR'd if it is needed
  52.  
  53. Set Temp$Dir <Wimp$ScrapDir>
  54. IF "<Temp$Dir>" = "" THEN Set Temp$Dir $
  55. Set AudioWorks$PanicDir <Temp$Dir>.AudioWorks
  56. UnSet Temp$Dir
  57.  
  58. |----------------------------------------------------------------------------
  59. | AudioWorks preference file name:
  60. | This is the only Writable resource used, so for network use you can
  61. | comment out this line and set the variable up as appropriate for individual
  62. | users, so that each user can have their own personal prefs
  63.  
  64. Set AudioWorks$Prefs <Obey$Dir>.AudioPrefs
  65.  
  66. |----------------------------------------------------------------------------
  67. | AudioWorks display fonts:
  68. | If you configure 'Outline font' on in the display preferences, the following
  69. | fonts will be used. FontSize is a size in 16ths of a point.
  70. | Note that if TitleFont is not set, AW will try to find an Italic/Oblique
  71. | variation of TextFont. If none of these are set, then AW will try Wimp$Font.
  72. | If the fonts chosen are not all available, AW will default to System font.
  73. |
  74. | The default below is to use Wimp$Font if it is set, else use Trinity.Medium
  75.  
  76. Set AudioWorks$TextFont <Wimp$Font>
  77. Set AudioWorks$FontSize <Wimp$FontSize>
  78. Unset AudioWorks$TitleFont
  79.  
  80. if "<Wimp$Font>" = "" then Set AudioWorks$TextFont Trinity.Medium
  81. if "<Wimp$Font>" = "" then Set AudioWorks$TitleFont Trinity.Medium.Italic
  82. if "<Wimp$Font>" = "" then Set AudioWorks$FontSize 224
  83.  
  84. |----------------------------------------------------------------------------
  85. | Oh, and of course, we mustn't forget to run the main program!
  86.  
  87. WimpSlot -min 240k -max 240k
  88. Run <AudioWorks$Dir>.!RunImage %*0